home *** CD-ROM | disk | FTP | other *** search
/ Belgian Amiga Club - ADF Collection / BS1 part 05.zip / BS1 part 5 / SASC_6.0_Disk_7.adf / Source_And_Examples / source / c.a < prev    next >
Encoding:
Text File  |  1992-07-30  |  40.4 KB  |  1,139 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4. * Use the following command line to make c.o
  5. * asm -u -isc:Assembler_Include/ c.a
  6. *
  7. * Use the following command line to make cres.o
  8. * asm -u -isc:Assembler_Include/ -dRESIDENT -ocres.o c.a
  9. *
  10. * Use the following command line to make catch.o (standard GURU catcher)
  11. * asm -u -isc:Assembler_Include/ -dCATCH -ocatch.o c.a
  12. *
  13. * Use the following command line to make catchnr.o (GURU catcher w/out requester)
  14. * asm -u -isc:Assembler_Include/ -dCATCH -dNOREQ -ocatchnr.o c.a
  15. *
  16. * Use the following command line to make catchres.o (resident GURU catcher)
  17. * asm -u -isc:Assembler_Include/ -dCATCH -dRESIDENT -ocatchres.o c.a
  18. *
  19. * Use the following command line to make catchresnr.o (resi GURU catcher w/out req)
  20. * asm -u -isc:Assembler_Include/ -dCATCH -dRESIDENT -dNOREQ -ocatchresnr.o c.a
  21. *
  22.         IFD  CATCH
  23.           IFND NOREQ
  24. AUTOREQ         set        1
  25.           ENDC
  26.         ENDC
  27.  
  28.         INCLUDE        "exec/types.i"
  29.         INCLUDE        "exec/alerts.i"
  30.         INCLUDE        "exec/nodes.i"
  31.         INCLUDE        "exec/lists.i"
  32.         INCLUDE        "exec/ports.i"
  33.         INCLUDE        "exec/libraries.i"
  34.         INCLUDE        "exec/tasks.i"
  35.         INCLUDE        "exec/memory.i"
  36.         INCLUDE        "exec/execbase.i"
  37.         INCLUDE        "libraries/dos.i"
  38.         INCLUDE        "libraries/dosextens.i"
  39.         INCLUDE        "workbench/startup.i"
  40.         INCLUDE        "exec/funcdef.i"
  41.         INCLUDE        "exec/exec_lib.i"
  42.         INCLUDE        "libraries/dos_lib.i"
  43.  
  44.         IFD   CATCH
  45.         INCLUDE        "intuition/intuition.i"
  46. VERSION  equ    1
  47. REVISION equ    0
  48.         ENDC
  49.         
  50. MEMFLAGS        EQU        MEMF_CLEAR+MEMF_PUBLIC
  51. AbsExecBase     EQU        4
  52.  
  53. ;;;
  54. ;;;   Stack map.
  55. ;;;
  56.       OFFSET  0
  57.            ds.b    4
  58. savereg    ds.b    13*4
  59. stackbtm   ds.b    4
  60.  
  61.  
  62.  
  63. ; some usefull macros:
  64.  
  65. callsys macro
  66.         CALLLIB _LVO\1
  67.         endm
  68.         
  69.         xdef        _XCEXIT                * exit(code) is standard way to leave C.
  70.         xdef        @_XCEXIT
  71.         
  72.         xref        LinkerDB        * linker defined base value
  73.         xref        _BSSBAS                * linker defined base of BSS
  74.         xref        _BSSLEN                * linker defined length of BSS
  75.         xref        __stack
  76.  
  77.        IFD          RESIDENT
  78.         xref        RESLEN
  79.         xref        RESBASE
  80.         xref        NEWDATAL
  81.        ENDC
  82.         
  83. *       library references
  84.  
  85.         section text,code
  86.  
  87.         xref    __main                  * Name of C program to start with.
  88.         xref    _MemCleanup             * Free all allocated memory
  89.         xref    __fpinit                * initialize floating point
  90.         xref    __fpterm                * terminate floating point
  91.  
  92. start:
  93.         movem.l d1-d6/a0-a6,-(a7)       * save registers
  94.  
  95.         move.l  a0,a2                   * save command pointer
  96.         move.l  d0,d2                   * and command length
  97.         lea     LinkerDB,a4             * load base register
  98.         move.l  AbsExecBase.W,a6
  99.  
  100.  
  101.         IFND        RESIDENT
  102.         lea     _BSSBAS,a3              * get base of BSS
  103.         moveq   #0,d1
  104.         move.l  #_BSSLEN,d0             * get length of BSS in longwords
  105.         bra.s   clr_lp                  * and clear for length given
  106. clr_bss move.l  d1,(a3)+
  107. clr_lp  dbf     d0,clr_bss
  108.         move.l  a7,_StackPtr(A4)        * Save stack ptr
  109.         move.l  a6,SysBase(A4)
  110.  
  111. *------ get the size of the stack, if CLI use cli_DefaultStack
  112. *------                                 if WB use a7 - TC_SPLOWER
  113.         move.l        ThisTask(a6),A3
  114.         move.l        pr_CLI(A3),d0
  115.         beq.s         fromwb
  116.         lsl.l         #2,d0
  117.         move.l        d0,a0
  118.         move.l        cli_DefaultStack(a0),d0
  119.         lsl.l         #2,d0             * # longwords -> # bytes
  120.         bra.s         dostack
  121.  
  122. fromwb:
  123.         move.l        a7,d0                         
  124.         sub.l         TC_SPLOWER(a3),d0
  125. dostack:
  126.  
  127. *------ Set __base for stack checking
  128.         move.l       a7,d1
  129.         sub.l        d0,d1               * get top of stack
  130.         add.l        #128,D1             * allow for parms overflow
  131.         move.l       D1,__base(A4)       * save for stack checking
  132.         
  133.         cmp.l         __stack(a4),d0
  134.         bcc.s        nochange        
  135.  
  136. *-- current stack is not as big as __stack says it needs
  137. *-- to be. Allocate a new one.
  138.         move.l        __stack(a4),d0
  139.         add.l         #128,d0           * extra room
  140.         move.l        d0,newstacksize(a4)
  141.  
  142.         move.l        #MEMFLAGS,d1
  143.         callsys       AllocMem
  144.         tst.l         d0
  145.         beq.w         return
  146.         
  147.         move.l        d0,newstack(a4)
  148.         add.l         #128,d0           * extra room
  149.         move.l        d0,__base(a4)
  150.         
  151.         add.l         __stack(a4),d0
  152.         move.l        d0,a7
  153.                 
  154. nochange:
  155.         ENDC
  156.  
  157.  
  158.  
  159.         IFD        RESIDENT
  160.         move.l        d2,-(a7)
  161.         movem.l       a0-a2,-(a7)
  162.  
  163. *------ get the size of the stack, if CLI use cli_DefaultStack
  164. *------                                 if WB use a7 - TC_SPLOWER
  165.         move.l        ThisTask(a6),A3
  166.         move.l        pr_CLI(A3),d1
  167.         beq.s         fromwb
  168.         lsl.l         #2,d1
  169.         move.l        d1,a0
  170.         move.l        cli_DefaultStack(a0),d1
  171.         lsl.l         #2,d1             * # longwords -> # bytes
  172.         bra.s         dostack
  173.  
  174. fromwb:
  175.         move.l        a7,d1                         
  176.         sub.l         TC_SPLOWER(a3),d1
  177. dostack:
  178.         moveq        #0,d2              * use d2 as flag for newstack or not
  179.         move.l       #RESLEN,d0
  180.         cmp.l        __stack(a4),d1     * This a4 is in the original 
  181.                                         * set of data
  182.         bcc.s        nochange        
  183.         move.l        __stack(a4),d1
  184.         add.l        d1,d0              * increase size of mem for new stack
  185.         moveq        #1,d2              * set flag
  186.                 
  187. nochange:
  188.         move.l        d1,a3             * save stacksize to set up stack checking
  189.         move.l        #MEMFLAGS,d1
  190.         callsys       AllocMem
  191.         tst.l         d0
  192.         bne.s         ok1
  193.         movem.l       (a7)+,d2/a0-a2
  194.         bra.w         return
  195.  
  196. ok1:    move.l        d0,a0
  197.         move.l        d0,a2             * a2 now has difference
  198.         
  199.         move.l        d0,a1
  200.         move.l        #NEWDATAL,d0
  201.         sub.l         #RESBASE,a4
  202.  
  203.                                         * copy data over
  204. cpy:    move.l        (a4)+,(a0)+
  205.         subq.l        #1,d0
  206.         bne.s         cpy
  207.  
  208.                                         * a4 now points at number of relocs
  209.         move.l        (a4)+,d0
  210. reloc:  beq.s         nreloc
  211.         move.l        a1,a0
  212.         add.l         (a4)+,a0          * a0 now has add of reloc
  213.         add.l         (a0),a2
  214.         move.l        a2,(a0) 
  215.         move.l        a1,a2             * restore offset
  216.         subq.l        #1,d0
  217.         bra.s         reloc
  218.         
  219. nreloc: move.l        a1,a4             * set up new base register
  220.         add.l         #RESBASE,a4
  221.  
  222.         move.l        #RESLEN,realdatasize(a4)
  223.         movem.l       (a7)+,a0-a2
  224.  
  225.         move.l        a6,SysBase(A4)
  226.         tst.b         d2
  227.         movem.l       (a7)+,d2          * restore d2 
  228.         movem.l       a7,_StackPtr(A4)  * Save stack ptr (movem doesn't
  229.                                         * change flags
  230.         beq.s         nochg2
  231.  
  232. *------ set up new stack
  233.         move.l       a4,d0
  234.         sub.l        #RESBASE,d0
  235.         add.l        #RESLEN,d0
  236.         add.l        __stack(a4),d0     * here a4 will be pointing at the
  237.                                         * new data, but __stack will be the
  238.                                         * same if all goes well
  239.         sub.l        #128,d0            * 128 down for good measure
  240.         move.l       d0,a7
  241.         move.l       __stack(a4),d0
  242.         move.l       d0,4(a7)            * fill in size of new stack        
  243.         add.l        d0,realdatasize(a4) * need to know how much to free later
  244.  
  245. nochg2:
  246. *------ Set __base for stack checking
  247.         move.l       a7,d1
  248.         sub.l        a3,d1               * get top of stack
  249.         add.l        #128,D1             * allow for parms overflow
  250.         move.l       D1,__base(A4)       * save for stack checking
  251.  
  252.         ENDC
  253.  
  254.  
  255.  
  256.         ifd     CATCH
  257.         move.w  AttnFlags(a6),Environment+2(a4) * save copy for dump
  258.         endc
  259.  
  260.  
  261.  
  262. clrwb:
  263.         clr.l        _WBenchMsg(A4)
  264.  
  265. *-----  clear any pending signals
  266.         moveq         #0,d0
  267.         move.l        #$00003000,d1
  268.         callsys       SetSignal
  269.         
  270.  
  271.         move.l        ThisTask(a6),A3
  272.  
  273.         ifd        CATCH
  274.         move.l        A3,TaskID(a4)
  275.  
  276. *------ initialize exception handler
  277. *------ Remember to preserve the old handler first
  278.         move.l        TC_TRAPDATA(a3),oldtrapdata(A4)
  279.         move.l        TC_TRAPCODE(a3),d0              ; check current exception
  280.         move.l        d0,oldtrapcode(A4)
  281.  
  282.         move.l        d0,a1
  283.         callsys TypeOfMem
  284.         tst.l d0
  285.         bne.s        1$                               * somebody else (debugger?) has vector
  286.  
  287.         move.l        #Exception,TC_TRAPCODE(a3)      * install pointers to code
  288.         move.l        a4,TC_TRAPDATA(a3)              * ...and data
  289. 1$:
  290.         ifd         AUTOREQ
  291. *------ attempt to open Intuition library:
  292.         bsr.w                openIntui
  293.         endc
  294.         endc
  295.  
  296.  
  297. *------ attempt to open DOS library:
  298.         lea           DOSName(PC),A1
  299.         moveq.l       #0,D0
  300.         callsys       OpenLibrary
  301.         move.l        D0,DOSBase(A4)
  302.         bne.s         ok2
  303.         moveq.l       #100,d0
  304.         bra.w         exit2
  305.  
  306. ok2:
  307.  
  308. *------ are we running as a son of Workbench?
  309.         move.l        pr_CurrentDir(A3),__curdir(A4)
  310.         tst.l         pr_CLI(A3)
  311.         beq.w         fromWorkbench
  312.         
  313. *=======================================================================
  314. *====== CLI Startup Code ===============================================
  315. *=======================================================================
  316. *
  317. * Entry: D2 = command length
  318. *        A2 = Command pointer
  319. fromCLI:
  320.         ifd        CATCH
  321.         moveq         #-1,d0
  322.         move.l        d0,Starter(a4)        * non-zero means CLI
  323.         move.l        a5,StackTop(a4)
  324.         endc
  325.  
  326. *------ find command name:
  327.         move.l      pr_CLI(a3),a0
  328.         add.l       a0,a0                   * bcpl pointer conversion
  329.         add.l       a0,a0
  330.         move.l      cli_CommandName(a0),a1
  331.  
  332.         IFD         CATCH 
  333.         IFND        AUTOREQ
  334.         move.l      cli_StandardOutput(a0),GConsole(a4)   * save output fh
  335.         ENDC
  336.         ENDC
  337.         
  338.         add.l       a1,a1                   * bcpl pointer conversion
  339.         add.l       a1,a1
  340.  
  341. *------ collect parameters:
  342.         move.l      d2,d0                   * get command line length
  343.         moveq.l     #0,d1
  344.         move.b      (a1)+,d1
  345.         move.l      a1,_ProgramName(A4)
  346.         add.l       d1,d0                   * add length of command name
  347.         addq.l      #7,d0                   * allow for space after command, quotes
  348.                                             * and null terminator, as well as 
  349.         andi.w      #$fffc,D0               * force to long word boundary
  350.         move.l      d0,Commandlen(a4)
  351.    
  352.         movem.l     d1/a1,-(a7)
  353.         move.l      #MEMFLAGS,d1
  354.         callsys     AllocMem
  355.         movem.l     (a7)+,d1/a1
  356.         tst.l       d0
  357.         bne.s       ok_copy
  358.    
  359.         move.l      #1000,d0                * what should the return code be for out of mem?
  360.         move.l      d0,-(a7)                * put a return code on the stack
  361.         beq.w       nodofree                * Was exitToDOS
  362.    
  363. ok_copy:
  364.         move.l      d0,a0
  365.         move.l      d0,Commandbuf(a4)
  366.          
  367. *------ copy command line into memory
  368.         move.l     d2,d0                    * get command line length
  369.         subq.l     #1,d0
  370.         add.l      d1,d2
  371.    
  372. copy_line:
  373.         move.b     0(A2,D0.W),2(A0,D2.W)    * copy command line to stack
  374.         subq.l     #1,d2
  375.         dbf        d0,copy_line
  376.         move.b     #' ',2(a0,d2.w)          * add space between command and parms
  377.         subq.l     #1,d2
  378.         move.b     #'"',2(a0,d2.w)          * add end quote
  379.    
  380. copy_cmd:
  381.         move.b     0(a1,d2.w),1(a0,d2.w)    * copy command name to stack
  382.         dbf        d2,copy_cmd
  383.         move.b     #'"',(a0)
  384.         move.l     A0,-(A7)                 * push command line address
  385.         bra.s      main                     * call C entrypoint
  386.  
  387. *=======================================================================
  388. *====== Workbench Startup Code =========================================
  389. *=======================================================================
  390.  
  391. fromWorkbench:
  392.  
  393.         ifd        CATCH
  394.         move.l     TC_SPUPPER(a3),StackTop(a4)  * set top of stack
  395.         endc
  396.  
  397.  
  398. *------ we are now set up.  wait for a message from our starter
  399.         lea        pr_MsgPort(A3),a0         * our process base
  400.         callsys    WaitPort
  401.         lea        pr_MsgPort(A3),a0         * our process base
  402.         callsys    GetMsg
  403.         move.l     d0,_WBenchMsg(a4)
  404.         move.l     d0,-(SP)
  405.  
  406.         move.l     d0,a2                     * get first argument
  407.         move.l     sm_ArgList(a2),d0
  408.         beq.s      do_main
  409.         move.l     DOSBase(a4),a6
  410.         move.l     d0,a0
  411.         move.l     wa_Lock(a0),d1
  412.         callsys    DupLock
  413.         move.l     d0,__curdir(A4)
  414.         move.l     d0,d1
  415.         callsys    CurrentDir
  416.  
  417. do_main:
  418.         move.l     _WBenchMsg(A4),a0         * get address of workbench message
  419.         move.l     a0,-(a7)                  * push argv
  420.         pea        NULL(a4)                  * push argc
  421.         move.l     sm_ArgList(a0),a0         * get address of arguments
  422.         move.l     wa_Name(a0),_ProgramName(A4) * get name of program
  423.  
  424. *=============================================
  425. *------ common code --------
  426. *=============================================
  427.  
  428. main    jsr        __fpinit(PC)              * Initialize floating point
  429.         jsr        __main(PC)                * call C entrypoint
  430.         moveq.l    #0,d0                     * set successful status
  431.         bra.s      exit2
  432. *
  433.  
  434. XCEXIT:
  435. _XCEXIT:
  436.         move.l     4(SP),d0                  * extract return code
  437. @XCEXIT:
  438. @_XCEXIT:
  439. exit2:
  440.         movea.l    _StackPtr(a4),a7          * restore stack ptr
  441.         move.l     d0,-(a7)
  442.         move.l     _ONEXIT(A4),d0            * exit trap function?
  443.         beq.s      exit3
  444.         move.l     d0,a0
  445.         jsr        (a0)
  446. exit3:
  447.         jsr        __fpterm(PC)              * clean up any floating point
  448.         jsr        _MemCleanup(PC)           * cleanup leftover memory alloc.
  449.  
  450.         ifnd       RESIDENT
  451. *------ free the stack if we allocated one
  452.         move.l     newstacksize(a4),d0
  453.         beq.s      exit4
  454.         move.l     newstack(a4),a1
  455.         move.l     AbsExecBase.W,A6
  456.         callsys    FreeMem
  457.         endc
  458.  
  459. exit4:
  460. *------ if we ran from CLI, skip workbench cleanup:
  461.         tst.l      _WBenchMsg(A4)
  462.         beq.s      exitToDOS
  463.         move.l     DOSBase(A4),a6
  464.         move.l     __curdir(a4),d1
  465.         beq.s      done_5
  466.         callsys    UnLock
  467. done_5:
  468. *------ return the startup message to our parent
  469. *       we forbid so workbench can't UnLoadSeg() us
  470. *       before we are done:
  471.         move.l     AbsExecBase.W,A6
  472.         callsys    Forbid
  473.         move.l     _WBenchMsg(a4),a1
  474.         callsys    ReplyMsg
  475.         bra.s      nodofree
  476.  
  477. exitToDOS:
  478.         move.l     AbsExecBase.W,a6
  479.  
  480. *------ Restore the original exception handler
  481.         ifd    CATCH
  482.         move.l        ThisTask(a6),A3
  483.         move.l        oldtrapdata(A4),TC_TRAPDATA(a3)
  484.         move.l        oldtrapcode(A4),TC_TRAPCODE(a3) * check current exception
  485.          ifd         AUTOREQ
  486.           move.l        IntuiBase(a4),a1
  487.           callsys         CloseLibrary                * close Intuition library
  488.          endc
  489.         ENDC
  490.  
  491. *------ free the command line buffer
  492.         move.l     Commandlen(a4),d0
  493.         beq.s      nodofree
  494.         move.l     Commandbuf(a4),a1
  495.         callsys    FreeMem
  496.    
  497. *------ this rts sends us back to DOS:
  498. nodofree:
  499.         move.l     DOSBase(A4),a1
  500.         callsys    CloseLibrary              * close Dos library
  501.  
  502.         IFD        RESIDENT
  503.         move.l     realdatasize(a4),d0
  504.         move.l     a4,a1
  505.         sub.l      #RESBASE,a1
  506.         callsys    FreeMem
  507.         ENDC
  508.         move.l     (a7)+,d0
  509.  
  510. return:        
  511.         movem.l    (a7)+,d1-d6/a0-a6
  512.         rts
  513.  
  514. DOSName dc.b    'dos.library',0
  515.  
  516.         ifd        CATCH
  517. *-----------------------------------------------------------------------
  518. *        Open the Intuition library:
  519.  
  520. openIntui:
  521.         lea        IntuiName(PC),A1
  522.         moveq.l    #0,D0
  523.         callsys    OpenLibrary
  524.         move.l     D0,IntuiBase(A4)
  525.         beq.s      noDOS
  526.         rts
  527.  
  528. *-----------------------------------------------------------------------
  529. noDOS:
  530.         moveq.l #100,d0
  531.         bra.w    exit2
  532.  
  533.  
  534. IntuiName  dc.b        'intuition.library',0
  535.  
  536. *-----------------------------------------------------------------------
  537. *        The Exception Handler - catches GURUs and exits (semi)cleanly
  538. Exception:
  539.         movem.l    a0,-(a7)
  540.         move.l     AbsExecBase.W,a0
  541.         move.l     ThisTask(a0),a0
  542.         move.l     TC_TRAPDATA(a0),a0        * ...and data
  543.         move.l     (sp)+,ADump(a0)           * save a0
  544.         move.l     d0,ADump+4(a0)            * and d0
  545.  
  546.         move.l     (a7)+,d0                  * get exception # from stack
  547.         move.l     d0,GURUNum(a0)            * and save it
  548.         cmpi.l     #3,d0                     * ADDRESS or BUS error?
  549.         bgt.s      1$                        * no, skip adjustment
  550.         btst       #0,Environment+3(a0)      * is it 68010 or 68020?
  551.         bne.s      1$                        * 0 means NO
  552.         addq.l     #8,a7                     * adjust for 68000
  553. 1$:
  554.         move.l     2(a7),d0                  * get PC at crash
  555.         move.l     d0,GURUAddr(a0)           * and save it
  556.         move.l     ADump+4(a0),d0            * restore a0 and d0
  557.         move.l     ADump(a0),a0
  558.         move.l     #GURUExit,2(a7)           * use our own exit point
  559.         rte
  560.         
  561. *-----------------------------------------------------------------------
  562. *        The Exception exit routine - write 'PGTB' IFF chunk to file
  563. *        'SnapShot.TB' in current directory, then exit to system.
  564.  
  565. GURUExit:
  566.         movem.l    d0-d7/a0-a7,-(sp)         * save all registers
  567.         move.l     AbsExecBase.W,a6          * make sure we are working with Exec
  568.         callsys    GetCC                     * safe way - works with all CPUs
  569.         move.l     ThisTask(a6),a3
  570.         move.l     TC_TRAPDATA(a3),a4        * make sure we have a valid # in a4
  571.         move.l     d0,Flags(a4)              * save area
  572.         movem.l    (sp)+,d0-d7
  573.         movem.l    d0-d7,DDump(a4)           * save data reg contents
  574.         movem.l    (sp)+,d0-d7
  575.         movem.l    d0-d7,ADump(a4)           * save address reg contents
  576.         tst.l      StackPtr(a4)              * if there's something there
  577.         bne        GExit1                    * ...we've been here before!
  578.         lea        TempStore(a4),a0          * calculate addr of TempStore
  579.         move.l     a0,TempAddr(a4)           * ...and save for later access
  580.         move.l     A7Store(a4),d0            * make sure we have proper TOS
  581.         move.l     d0,StackPtr(a4)           * ...and save it
  582.         moveq      #0,d0
  583.         move.l     _ProgramName(a4),a0       * find length of program name
  584.  
  585.         ifd        AUTOREQ
  586.         move.l     a0,PName(a4)
  587.         endc
  588.  
  589.         subq.l     #1,a0
  590.         move.b     (a0),d0
  591.         addq.l     #4,d0                     * adjust for shift
  592.         lsr.l      #2,d0
  593.         move.l     d0,NameLen(a4)            * store length
  594.         add.l      d0,FAILlen(a4)            * and sub-chunk total
  595.  
  596.         moveq      #0,d0                     * clear d0 for use
  597.         lea        VBlankFrequency(a6),a0    * set up a0 to find correct data
  598.         move.b     (a0)+,d0                  * get just in case
  599.         move.l     d0,VBlankFreq(a4)         * ...so we can figure what
  600.         move.b     (a0),d0                   * ...type of machine
  601.         move.l     d0,PowerSupFreq(a4)       * ...we're working on
  602.  
  603.         lea        start-4(pc),a0            * get seglist ptr
  604.         moveq      #-1,d0                    * always at least 1
  605. 2$:
  606.         addq.l     #1,d0
  607.         move.l     (a0),d1                   * find end of list
  608.         beq.s      3$
  609.         lsl.l      #2,d1                     * BPTR!!!!!
  610.         move.l     d1,a0
  611.         bra.s      2$
  612. 3$:
  613.         add.l      d0,SegCount(a4)           * store # of seglist pointers
  614.         lsl.l      #1,d0                     * multiply by 2 for longword count
  615.         add.l      d0,FAILlen(a4)            * and sub-chunk length
  616.  
  617.         move.l     StackTop(a4),d0           * get top of stack
  618.         sub.l      StackPtr(a4),d0           * find number of bytes used
  619.         addq.l     #4,d0                     * adjust for longword conversion
  620.         lsr.l      #2,d0                     * convert from bytes to long
  621.         move.l     d0,StackLen(a4)           * and save
  622.         add.l      d0,s2len(a4)              * and sub-chunk total
  623.  
  624.         move.l     a5,-(sp)                  * save a5 for later
  625.         callsys    Forbid                    * don't let 'em change while we ask
  626.         move.l     MemList+LH_HEAD(a6),d0    * first node in MemList
  627. checkchip:
  628.         move.l     d0,a5                     * move node address to address reg
  629.         move.w     MH_ATTRIBUTES(a5),d4      * get node attributes
  630.         btst       #MEMB_CHIP,d4             * is it chip?
  631.         beq.s      checkfast                 * no, go on
  632.         lea        chipAvail(a4),a3
  633.         bsr.w      AddIt
  634. checkfast:
  635.         btst       #MEMB_FAST,d4             * is it fast?
  636.         beq.s      next                      * no, go on
  637.         lea        fastAvail(a4),a3
  638.         bsr.w      AddIt
  639. next:
  640.         move.l     LN_SUCC(a5),d0            * get address of next node
  641.         bne.s      checkchip                 * ...and loop back if valid
  642.         callsys    Permit                    * allow others access again
  643.         move.l     #MEMF_CHIP+MEMF_LARGEST,d1 * to find largest hunk in chip ram
  644.         callsys    AvailMem
  645.         move.l     d0,chipLargest(a4)         * store
  646.         move.l     #MEMF_FAST+MEMF_LARGEST,d1 * to find largest hunk in fast ram
  647.         callsys    AvailMem
  648.         move.l     d0,fastLargest(a4)        * store
  649.         move.l     (sp)+,a5                  * and restore a5
  650.  
  651.         ifd        AUTOREQ
  652.         moveq      #0,d0                     * PosFlag
  653.         move.l     d0,d1                     * NegFlag
  654.         move.l     d0,a0                     * 0 means use current window
  655.         lea        IText1(a4),a1             * Body Text
  656.         lea        IText5(a4),a2             * Positive Gadget Text
  657.         lea        IText6(a4),a3             * Negative Gadget Text
  658.         moveq      #1,d2
  659.         lsl.l      #8,d2                     * quick way to set Width
  660.         moveq      #76,d3                    * Height
  661.         move.l     IntuiBase(a4),a6          * get intuition library pointer
  662.         jsr        -$15c(A6)                 * callsys       AutoRequest
  663.         move.l     AbsExecBase.W,a6
  664.         tst.l      d0                        * save SnapShot?
  665.         beq.w      GExit2                    * no, just exit
  666.         endc
  667.  
  668.         move.l     DOSBase(a4),a6
  669.         lea        DumpName(a4),a0           * get name of output file
  670.         move.l     a0,d1
  671.         move.l     #MODE_NEWFILE,d2          * create new file
  672.         callsys    Open 
  673.         bne.s      4$
  674.         lea        DumpPath(a4),a0           * if error in current dir, try DF1:
  675.         move.l     a0,d1
  676.         move.l     #MODE_NEWFILE,d2
  677.         callsys    Open
  678.         bne.s      4$
  679.         move.b     #'0',DumpPath+2(a4)       * still error?  Try DF0:
  680.         lea        DumpPath(a4),a0
  681.         move.l     a0,d1
  682.         move.l     #MODE_NEWFILE,d2
  683.         callsys    Open
  684.  
  685.         ifnd        AUTOREQ
  686.         bne.s      4$                        * if no error, continue (finally!)
  687.         move.l     GConsole(a4),d1
  688.         beq.w      GExit2
  689.         lea        failmsg(a4),a0
  690.         move.l     a0,d2
  691.         move.l     #23,d3
  692.         callsys    Write
  693.         endc
  694.  
  695.         bra.w      GExit2                    * else, print msg & DIE gracefully
  696. 4$:
  697.         move.l     d0,d5                     * save file handle for Write
  698.         move.l     d0,fp(a4)                 * ...and in a safe place for later
  699.         move.l     d5,d1                     * get file handle
  700.         lea        PGTB(a4),a0               * first part of fixed
  701.         move.l     a0,d2
  702.         move.l     #chunk_len_1,d3           * length of first
  703.         callsys    Write                     * ...since it gets written over
  704.  
  705.         move.l     d5,d1                     * get file handle
  706.         move.l     _ProgramName(a4),d2       * get address of program name
  707.         move.l     NameLen(a4),d3            * get # longs in program name
  708.         lsl.l      #2,d3                     * ..and convert to bytes
  709.         callsys    Write
  710.  
  711.         move.l     d5,d1                     * get file handle
  712.         lea        Environment(a4),a0        * second part of fixed
  713.         move.l     a0,d2
  714.         move.l     #chunk_len_2,d3           * length of second part
  715.         callsys    Write
  716.  
  717.         lea        start-8(pc),a0            * address of seglist (size of seg)
  718.         move.l     (a0)+,d0                  * segsize
  719.         move.l     d0,TempStore+4(a4)        * save it
  720.         move.l     a0,TempStore(a4)          * store first number
  721.         move.l     SegCount(a4),d4
  722. 5$:
  723.         move.l     d5,d1                     * get file handle
  724.         move.l     TempAddr(a4),d2           * address of write buffer
  725.         moveq      #TempSize,d3              * size of segment pointer
  726.         callsys    Write
  727.         move.l     TempStore(a4),a0          * retrieve pointer
  728.         move.l     (a0),d0                   * get next seg pointer
  729.         lsl.l      #2,d0                     * adjust
  730.         move.l     d0,TempStore(a4)          * ..and save
  731.         move.l     d0,a0
  732.         beq.b      donesegs                  * last segment?
  733.         move.l     -4(a0),d0                 * get segsize
  734.         move.l     d0,TempStore+4(a4)        * ...and save it
  735.         subq.l     #1,d4                     * done yet?
  736.         bne.s      5$                        * no, do next
  737.  
  738. donesegs:
  739.         tst.l      _FMEM(a4)                 * do they want memory reported?
  740.         beq.s      55$                       * no, forget it
  741.         move.l     d5,d1
  742.         lea        subFMEM(a4),a0
  743.         move.l     a0,d2
  744.         move.l     #FMEMlen,d3
  745.         callsys    Write
  746.  
  747. 55$:
  748.         move.l     d5,d1                     * (get the idea?)
  749.         lea        subREGS(a4),a0            * third part of fixed
  750.         move.l     a0,d2
  751.         move.l     #chunk_len_3,d3           * length of third
  752.         callsys    Write
  753.  
  754.         move.l     StackLen(a4),d0           * get length of stack used
  755.         cmpi.l     #2048,d0                  * > 8k ?
  756.         bgt.s      6$                        * yes, dump two chunks
  757.         move.l     d5,d1
  758.         lea        STAK2(a4),a0              * whole stack chunk
  759.         move.l     a0,d2
  760.         moveq      #STAK2len,d3              * length of fixed part
  761.         callsys    Write
  762.  
  763.         move.l     d5,d1
  764.         move.l     StackPtr(a4),d2           * address of stack
  765.         move.l     StackLen(a4),d3           * get # longwords on stack
  766.         lsl.l      #2,d3                     * ..and convert to bytes
  767.         callsys    Write
  768.         bra.s      7$
  769. 6$:
  770.         move.l     d5,d1
  771.         lea        STAK3(a4),a0              * top4k chunk
  772.         move.l     a0,d2
  773.         moveq      #STAK3len,d3              * length of fixed part
  774.         callsys    Write
  775.  
  776.         move.l     d5,d1
  777.         move.l     StackTop(a4),d2           * find top of stack
  778.         sub.l      #4096,d2                  * find top-4k
  779.         move.l     #4096,d3                  * # bytes to write
  780.         callsys    Write
  781.  
  782.         move.l     d5,d1
  783.         lea        STAK4(a4),a0              * bottom4k chunk
  784.         move.l     a0,d2
  785.         moveq      #STAK4len,d3              * length of fixed part
  786.         callsys    Write
  787.  
  788.         move.l     d5,d1
  789.         move.l     StackPtr(a4),d2           * current stack address
  790.         move.l     #4096,d3                  * # bytes to write
  791.         callsys    Write
  792. 7$:
  793.         move.l     _STAKOffset(a4),d3
  794.         beq.s      8$
  795.         lsr.l      #2,d3
  796.         addq.l     #1,d3
  797.         move.l     d3,_STAKOffset(a4)
  798.         addq.l     #1,d3
  799.         move.l     d5,d1
  800.         lea        STAK5(a4),a0
  801.         move.l     a0,d2
  802.         moveq      #STAK5len,d3
  803.         callsys    Write
  804.  
  805.         move.l     d5,d1
  806.         move.l     StackPtr(a4),d2
  807.         move.l     _STAKOffset(a4),d3
  808.         subq.l     #1,d3
  809.         move.l     StackLen(a4),d4
  810.         cmp.l      d3,d4
  811.         bge.s      75$
  812.         move.l     StackLen(a4),d3
  813. 75$:
  814.         lsl.l      #2,d3
  815.         callsys    Write
  816. 8$:
  817.         tst.l      _ONGURU(A4)               * user GURU function?
  818.         beq.s      9$
  819.         move.l     d5,-(sp)
  820.         move.l     d5,d1
  821.         lea        UDAT(a4),a0
  822.         move.l     a0,d2
  823.         move.l     #UDATlen,d3
  824.         callsys    Write
  825.         move.l     d5,d1
  826.         moveq      #0,d2                     * zero offset
  827.         moveq      #1,d3                     * ...from EOF
  828.         callsys    Seek
  829.         move.l     d0,SeekStore(a4)
  830.         move.l     _ONGURU(a4),a0
  831.         jsr        (a0)
  832.         addq.l     #4,sp
  833. 9$:
  834.         move.l     fp(a4),d5
  835.         move.l     d5,d1
  836.         moveq      #0,d2                     * offset from EOF
  837.         moveq      #1,d3                     * OFFSET_END
  838.         callsys    Seek                      * Seek returns OLD position
  839.         move.l     d0,d1
  840.         andi.l     #3,d1                     * did user write even longwords?
  841.         beq.s      10$                       * Yep!        Nice Human.
  842.         move.l     d1,d6                     * Nope, save for later.
  843.         clr.l      TempStore(a4)             * clear temp storage
  844.         move.l     d5,d1
  845.         move.l     TempAddr(a4),d2
  846.         moveq      #4,d3
  847.         sub.l      d6,d3                     * find how many NULLs to pad
  848.         callsys    Write
  849.         bra.s      9$
  850. 10$:
  851.         tst.l      SeekStore(a4)             * did we write UDAT?
  852.         beq.s      11$                       * nope!
  853.         sub.l      SeekStore(a4),d0          * find length of UDAT section
  854.         lsr.l      #2,d0                     * adjust to longwords
  855.         move.l     d0,TempStore(a4)          * save UDAT length for write
  856.         move.l     d5,d1
  857.         move.l     SeekStore(a4),d2          * find where to write it
  858.         subq.l     #4,d2
  859.         moveq      #-1,d3                    * OFFSET_BEGINNING
  860.         callsys    Seek
  861.         move.l     d5,d1
  862.         move.l     TempAddr(a4),d2
  863.         move.l     #4,d3
  864.         callsys    Write                     * write length of UDAT field to file
  865. 11$:
  866.         move.l     d5,d1
  867.         moveq      #0,d2                     * offset to 'Length' field
  868.         moveq      #1,d3                     * OFFSET_END
  869.         callsys    Seek                      * make sure we are at end of file
  870.         move.l     d5,d1
  871.         moveq      #4,d2                     * offset to 'Length' field
  872.         moveq      #-1,d3                    * OFFSET_BEGINNING
  873.         callsys    Seek
  874.         subq.l     #8,d0                     * adjust total length
  875.         lsr.l      #2,d0                     * adjust to longwords
  876.         move.l     d0,TempStore(a4)          * save for write
  877.         move.l     d5,d1
  878.         move.l     TempAddr(a4),d2
  879.         move.l     #4,d3
  880.         callsys    Write                     * write 'Length' field
  881. GExit1:
  882.         move.l     fp(a4),d1
  883.         beq.s      GExit2
  884.         move.l     DOSBase(a4),a6
  885.         callsys    Close
  886.  
  887.         ifnd        AUTOREQ
  888.         move.l      GConsole(a4),d1
  889.         beq.s       GExit2
  890.         lea         success(a4),a0
  891.         move.l      a0,d2
  892.         move.l      #32,d3
  893.         callsys     Write
  894.         endc
  895.         
  896. GExit2:
  897.         move.l       TaskID(a4),a6
  898.         move.l       AbsExecBase.W,a6
  899.         moveq        #$47,d0
  900.         bra.w        exit2
  901.  
  902. *-----------------------------------------------------------------------
  903. * AddIt:        routine to add memory parts to variables
  904.  
  905. AddIt:
  906.         move.l       MH_FREE(a5),d0
  907.         add.l        d0,(a3)                 * add to available
  908.         move.l       MH_UPPER(a5),d0
  909.         sub.l        MH_LOWER(a5),d0
  910.         add.l        d0,4(a3)                * add to Max section
  911.         rts
  912.         endc
  913.  
  914.  
  915.         IFD     CATCH
  916.         section __MERGED,DATA
  917. _ONGURU        dc.l        0
  918. IntuiBase      dc.l        0
  919. TaskID         dc.l        0
  920. oldtrapcode    dc.l        0
  921. oldtrapdata    dc.l        0
  922.  
  923.         ifnd        AUTOREQ
  924. GConsole        dc.l        0
  925. failmsg         dc.b        7,'Can''t write SnapShot!',10
  926. success         dc.b        7,'GURU caught; SnapShot written!',10
  927.         endc
  928.  
  929.         cnop        0,4
  930. _FMEM           dc.l        0
  931. fp              dc.l        0                  * save SnapShot file pointer
  932. DumpPath        dc.b        'DF1:'
  933. DumpName        dc.b        'SnapShot.TB',0
  934. SeekStore       dc.l        0
  935. TempAddr        dc.l        0                  * Storage for &TempStore
  936. TempStore       dc.l        0,0                * Temporary storage for BPTR -> APTR
  937. TempSize        equ        *-TempStore
  938.  
  939.         cnop        0,4
  940.         ifd        AUTOREQ
  941. TAttr:                                         * Text attributes for font
  942.         dc.l        TName                      * name of font
  943.         dc.w        TOPAZ_EIGHTY               * font size
  944.         dc.b        FS_NORMAL                  * font style
  945.         dc.b        FPF_ROMFONT                * font preferences
  946. TName:
  947.         dc.b        'topaz.font',0
  948.         cnop        0,4
  949.  
  950. IText1:                                        * Text definitions for AutoReq call
  951.         dc.b        3,0,RP_JAM1,0              * front & back pens, drawmode and filler byte
  952.         dc.w        6,4                        * XY origin relative to container TopLeft
  953.         dc.l        TAttr                      * font pointer or NULL for default
  954.         dc.l        ITextText1                 * pointer to text
  955.         dc.l        IText2                     * next IntuiText structure
  956. ITextText1:
  957.         dc.b        'Program:',0
  958.         cnop 0,4
  959. IText2:
  960.         dc.b        3,0,RP_JAM1,0
  961.         dc.w        78,4
  962.         dc.l        TAttr
  963. PName   dc.l        0
  964.         dc.l        IText3
  965.         cnop        0,4
  966. IText3:
  967.         dc.b        3,0,RP_JAM1,0
  968.         dc.w        55,16
  969.         dc.l        TAttr
  970.         dc.l        ITextText3
  971.         dc.l        IText4
  972. ITextText3:
  973.         dc.b        'I caught a GURU!',0
  974.         cnop 0,4
  975. IText4:
  976.         dc.b        3,0,RP_JAM1,0
  977.         dc.w        20,28
  978.         dc.l        TAttr
  979.         dc.l        ITextText4
  980.         dc.l        0
  981. ITextText4:
  982.         dc.b        'Should I make a SnapShot?',0
  983.         cnop 0,4
  984. IText5:
  985.         dc.b        3,0,RP_JAM2,0
  986.         dc.w        6,3
  987.         dc.l        TAttr
  988.         dc.l        ITextText5
  989.         dc.l        0
  990. ITextText5:
  991.         dc.b        'YES',0
  992.         cnop 0,4
  993. IText6:
  994.         dc.b        3,0,RP_JAM2,0
  995.         dc.w        6,3
  996.         dc.l        TAttr
  997.         dc.l        ITextText6
  998.         dc.l        0
  999. ITextText6:
  1000.         dc.b        'NO',0
  1001.         endc
  1002.  
  1003.         cnop 0,4
  1004.  
  1005. *--------------------------------------------------------------------------
  1006. * New IFF chunk format -
  1007. *        PGTB = Program Traceback, header for chunk
  1008. *        FAIL = reason for and environment of crash
  1009. *        REGS = registers at time of crash, including PC and CCR
  1010. *        VERS = version, revision, name of this program
  1011. *        STAK = ENTIRE stack at time of crash or, alternately,
  1012. *                the top and bottom 4k if the stack used is > 8k
  1013. *        UDAT = optional user data dump (if _ONGURU is set to a
  1014. *                function pointer in the user's program)
  1015. *--------------------------------------------------------------------------
  1016.  
  1017. PGTB            dc.b        'PGTB'
  1018. Length          dc.l        0                * length of chunk (in longwords)
  1019.  
  1020. subFAIL         dc.b        'FAIL'
  1021. FAILlen         dc.l        9
  1022. NameLen         dc.l        0                * length of program name
  1023. chunk_len_1     equ         *-PGTB
  1024. Environment     dc.l        0                * CPU (, Math)
  1025. VBlankFreq      dc.l        0                *        PAL = 50, NTSC = 60 (approx.)
  1026. PowerSupFreq    dc.l        0                * Europe = 50,        USA = 60 (approx.)
  1027. Starter         dc.l        0                * 0 = WB, -1 = CLI
  1028. GURUNum         dc.l        0                * cause of crash (GURU #)
  1029. SegCount        dc.l        1                * # hunks in seglist
  1030. chunk_len_2     equ         *-Environment
  1031.  
  1032. subFMEM         dc.b        'FMEM'           * FMEM - free memory at crash
  1033.                 dc.l        6
  1034. chipAvail       dc.l        0                * available chip memory
  1035. chipMax         dc.l        0                *        maximum chip memory
  1036. chipLargest     dc.l        0                *        largest chip memory
  1037. fastAvail       dc.l        0                * available fast memory
  1038. fastMax         dc.l        0                *        maximum fast memory
  1039. fastLargest     dc.l        0                *        largest fast memory
  1040. FMEMlen         equ         *-subFMEM
  1041.  
  1042. subREGS         dc.b        'REGS'           * REGS - register storage field
  1043. REGSlen         dc.l        18
  1044. GURUAddr        dc.l        0                * PC at time of crash
  1045. Flags           dc.l        0                * Condition Code Register (CCR)
  1046. DDump           dc.l        0,0,0,0,0,0,0,0  * data registers
  1047. ADump           dc.l        0,0,0,0,0,0,0    * address registers
  1048. A7Store         dc.l        0
  1049.  
  1050. subVERS         dc.b        'VERS'           * VERS - program version field
  1051.                 dc.l        6
  1052.                 dc.l        VERSION          * version #
  1053.                 dc.l        REVISION         * revision #
  1054.                 dc.l        3                * length of name of program
  1055.                 IFD        RESIDENT
  1056.                 dc.b        'catchres.o',0,0 * name
  1057.                 ENDC
  1058.                 IFND        RESIDENT
  1059.                 dc.b        'catch.o   ',0,0 * name
  1060.                 ENDC
  1061.  
  1062. subSTAK         dc.b        'STAK'           * STAK - stack field
  1063. STAKlen         dc.l        4
  1064. Type            dc.l        0                * 0 = Info
  1065. StackTop        dc.l        0                * top of stack pointer
  1066. StackPtr        dc.l        0                * current Stack Pointer
  1067. StackLen        dc.l        0                * # bytes used on stack
  1068. chunk_len_3     equ         *-subREGS
  1069.  
  1070. STAK2           dc.b        'STAK'
  1071. s2len           dc.l        1                * length of subtype
  1072.                 dc.l        1                * 1 = whole stack
  1073. STAK2len        equ         *-STAK2
  1074.  
  1075. STAK3           dc.b        'STAK'
  1076.                 dc.l        1025
  1077.                 dc.l        2                * 2 = top 4k of stack
  1078. STAK3len        equ         *-STAK3
  1079.  
  1080. STAK4           dc.b        'STAK'
  1081.                 dc.l        1025
  1082.                 dc.l        3                * 3 = bottom 4k of stack
  1083. STAK4len        equ         *-STAK4
  1084.  
  1085. STAK5           dc.b        'STAK'
  1086. _STAKOffset     dc.l        0
  1087.                 dc.l        4                * 4 = user defined amount
  1088. STAK5len        equ         *-STAK5
  1089.  
  1090. UDAT            dc.b        'UDAT'
  1091.                 dc.l        0
  1092. UDATlen         equ         *-UDAT
  1093.         endc
  1094.  
  1095.  
  1096.  
  1097.         section __MERGED,BSS
  1098.  
  1099.         xref    DOSBase
  1100.  
  1101.         xdef    NULL,SysBase,_WBenchMsg
  1102.         xdef    __curdir
  1103.         xdef    _OSERR,_FPERR,_SIGFPE,_ONERR,_ONEXIT,_ONBREAK
  1104.         xdef    _SIGINT
  1105.         xdef    _ProgramName,_StackPtr,__base
  1106.         ifd        CATCH
  1107.         xdef        _ONGURU,_FMEM,_STAKOffset
  1108.         endc
  1109.  
  1110.  
  1111.         
  1112. NULL         ds.b    4        
  1113. __base       ds.b    4                   * base of stack
  1114. _OSERR       ds.b    4
  1115. _FPERR       ds.b    4
  1116. _SIGFPE      ds.b    4
  1117. _SIGINT      ds.b    4
  1118. _ONERR       ds.b    4
  1119. _ONEXIT      ds.b    4
  1120. _ONBREAK     ds.b    4
  1121. __curdir     ds.b    4
  1122. SysBase      ds.b    4
  1123. _WBenchMsg   ds.b    4
  1124. _StackPtr    ds.b    4
  1125. _ProgramName ds.b    4
  1126. Commandbuf   ds.b    4
  1127. Commandlen   ds.b    4
  1128.  
  1129.         ifd        RESIDENT
  1130. realdatasize ds.b    4                   * size of memory allocated for data +
  1131.                                          * possible stack
  1132.         endc
  1133.         ifnd       RESIDENT
  1134. newstack     ds.b    4                   * pointer to new stack (if needed)
  1135. newstacksize ds.b    4                   * size of new stack
  1136.         endc
  1137.  
  1138.              END
  1139.